"My first proper macro"

Objective: apply a simple analysis pipeline over a set of images

Let's consider re-usability and generalization

• Download our test data to your desktop.
• Unzip (right click and "Extract All")
• Make another folder on the desktop called Output
• Open Script Editor ([File > New > Script...]) and start with an ImageJ macro template:
  [Templates > ImageJ 1.x > Batch > Process Folder (ImageJ macro)]

Process_Folder Template

[Templates > ImageJ 1.x > Batch > Process Folder (IJ1 macro)]

#@ File (label = "Input directory", style = "directory") input
#@ File (label = "Output directory", style = "directory") output
#@ String (label = "File suffix", value = ".tif") suffix

processFolder(input);

// function to scan folders/subfolders/files to find files with correct suffix
function processFolder(input) {
	list = getFileList(input);
	list = Array.sort(list);
	for (i = 0; i < list.length; i++) {
		if(File.isDirectory(input + File.separator + list[i]))
			processFolder(input + File.separator + list[i]);
		if(endsWith(list[i], suffix))
			processFile(input, output, list[i]);
	}
}

function processFile(input, output, file) {
	// Do the processing here by adding your own code.
	// Leave the print statements until things work, then remove them.
	print("Processing: " + input + File.separator + file);
	print("Saving to: " + output);
} 

Exercise Hints

• Use each macro as the basis for the next one.
• Remember the macro recorder!
• The list of all built-in functions is EXTREMELY useful!
• You can refer to the slide deck: https://thejacksonlaboratory.github.io/ fiji_workshops/IntermediateFiji_macros.html

Task 1- Create a macro that:

1. Opens every image, prints how many slices there are in the image and then closes the image.

i.e. you shouldn't have all of the image open at the end

Task 2- Create a macro that:

1. Opens every image, prints how many slices there are in the image...
2. duplicates the first slice
3. then saves this as a separate image (with a suitable filename).
4. Closes all the images.

Task 3- Create a macro that:

1. Opens every image, prints how many slices there are in the image, then...
2. Sets the slice to 5, duplicates this frame,
3. performs background subtraction then saves this as a separate image (with a suitable filename).
4. Closes all the images.

Task 4- Create a macro that:

1. Opens every image, prints how many slices there are in the image, then...
2. Loops through every individual slice of the image, subtracts the background and saves each as new image.
3. Closes all the images.

Extension task 5- Create a macro that:

1. Opens every image, prints how many slices there are in the image, then...
2. Loops through every individual slice of the image and saves each as new image.
3. Does a Z projection between slices 3 and 7 and measures the "mean gray value" of this projection.
4. Closes all the images and then saves the results table as a .csv file.

Solution 1:

#@ File (label = "Input directory", style = "directory") input
#@ File (label = "Output directory", style = "directory") output
#@ String (label = "File suffix", value = ".tif") suffix

processFolder(input);

// function to scan folders/subfolders/files to find files with correct suffix
function processFolder(input) {
	list = getFileList(input);
	list = Array.sort(list);
	for (i = 0; i < list.length; i++) {
		if(File.isDirectory(input + File.separator + list[i]))
			processFolder(input + File.separator + list[i]);
		if(endsWith(list[i], suffix))
			processFile(input, output, list[i]);
	}
}

function processFile(input, output, file) {
	open(input+File.separator+file);
	print(nSlices);
	close();
}

Solution 2:

#@ File (label = "Input directory", style = "directory") input
#@ File (label = "Output directory", style = "directory") output
#@ String (label = "File suffix", value = ".tif") suffix

processFolder(input);

// function to scan folders/subfolders/files to find files with correct suffix
function processFolder(input) {
	list = getFileList(input);
	list = Array.sort(list);
	for (i = 0; i < list.length; i++) {
		if(File.isDirectory(input + File.separator + list[i]))
			processFolder(input + File.separator + list[i]);
		if(endsWith(list[i], suffix))
			processFile(input, output, list[i]);
	}
}

function processFile(input, output, file) {	
	open(input+ File.separator +file);
	print(nSlices);
	run("Duplicate...", " ");
	saveAs("Tiff", output+File.separator+File.nameWithoutExtension+"_slice1" + suffix);
	close();
	close();
	//or close("*")
}

Solution 3:

#@ File (label = "Input directory", style = "directory") input
#@ File (label = "Output directory", style = "directory") output
#@ String (label = "File suffix", value = ".tif") suffix

processFolder(input);

// function to scan folders/subfolders/files to find files with correct suffix
function processFolder(input) {
	list = getFileList(input);
	list = Array.sort(list);
	for (i = 0; i < list.length; i++) {
		if(File.isDirectory(input + File.separator + list[i]))
			processFolder(input + File.separator + list[i]);
		if(endsWith(list[i], suffix))
			processFile(input, output, list[i]);
	}
}

function processFile(input, output, file) {	
	open(input+ File.separator +file);
	print(nSlices);
	setSlice(5);
	run("Duplicate...", " ");
	run("Subtract Background...", "rolling=20");
	saveAs("tiff", output+File.separator+File.nameWithoutExtension+"_slice5"+ suffix);
	close("*");
}

Solution 4:

#@ File (label = "Input directory", style = "directory") input
#@ File (label = "Output directory", style = "directory") output
#@ String (label = "File suffix", value = ".tif") suffix

processFolder(input);

// function to scan folders/subfolders/files to find files with correct suffix
function processFolder(input) {
	list = getFileList(input);
	list = Array.sort(list);
	for (i = 0; i < list.length; i++) {
		if(File.isDirectory(input + File.separator + list[i]))
			processFolder(input + File.separator + list[i]);
		if(endsWith(list[i], suffix))
			processFile(input, output, list[i]);
	}
}

function processFile(input, output, file) {	
	open(input+ File.separator +file);
	print(nSlices);
	for (i=1; i<=nSlices; i++){
		setSlice(i);
		run("Duplicate...", " ");
		run("Subtract Background...", "rolling=20");
		// Note: if you change the file type, e.g. to PNG, saveAs will yield the new name as File.nameWithoutExtension
		// So then you will want to store the initial File.nameWithoutExtension in a variable before this loop
		saveAs("tiff", output+File.separator+File.nameWithoutExtension+"_slice"+i+suffix);
		close();
	}
	close();
}

Solution 5:

#@ File (label = "Input directory", style = "directory") input
#@ File (label = "Output directory", style = "directory") output
#@ String (label = "File suffix", value = ".tif") suffix

processFolder(input);

// function to scan folders/subfolders/files to find files with correct suffix
function processFolder(input) {
	list = getFileList(input);
	list = Array.sort(list);
	for (i = 0; i < list.length; i++) {
		if(File.isDirectory(input + File.separator + list[i]))
			processFolder(input + File.separator + list[i]);
		if(endsWith(list[i], suffix))
			processFile(input, output, list[i]);
	}
}

function processFile(input, output, file) {	
	open(input+ File.separator +file);
	print(nSlices);
	for (i=1; i<=nSlices; i++){
		setSlice(i);
		run("Duplicate...", " ");
		run("Subtract Background...", "rolling=20");
		// Note: if you change the file type, e.g. to PNG, saveAs will yield the new name as File.nameWithoutExtension
		// So then you will want to store the initial File.nameWithoutExtension in a variable before this loop
		saveAs("tiff", output+File.separator+File.nameWithoutExtension+"_slice"+i+suffix);
		close();
	}
	run("Z Project...", "start=3 stop=7 projection=[Average Intensity]");
	run("Set Measurements...", "mean redirect=None decimal=7");
	run("Measure");
	saveAs("tiff", output+File.separator+File.nameWithoutExtension+"_projection_BackSubtract" + suffix);
	close("*");
}

// Important: this is outside the processFile function!
saveAs("Results", output+File.separator+"MeanIntensity.csv");